{{tag>software sysadmin gnuplot graphe todo}}

====== Graphe analyse des performances ======

Le collecteur de donnée produit un fichier csv contenant les éléments observés ici:
  * Utilisation processeur(%), 
  * Données émise sur le réseau Octets/s
  * Données recues sur l'interface réseau (Octets/s)

Ci dessous le fichier csv 
<file>

</file>

<file>
# ===== Configuration du terminal =====
#
#set terminal dumb
#set terminal pngcairo transparent 
#set terminal svg size 350,262 fname 'Verdana' fsize 10
set terminal pngcairo notransparent 
set terminal pngcairo size 2048, 480

set output "graphe.png"

# ===== Configuration de l' entrée =====
#
set datafile separator ","
data_file='Compteur de performance.csv'

# ===== Mise en forme du graphe =====

set title "Mesures serveur Hestia"
# prévoir une marge de 10 px sous le graphe pour le commentaire de génération 
set bmargin 10

# Mise en forme de la légende
set key autotitle columnhead
set key box
# set key at 6.1,1.3

# Axes label
set xlabel "Heure\nDate" 
set ylabel "Utilisation processeur"
set y2label "E/S interface réseau"

# Axes ranges
set yrange [0:100]

# Axes tics
set xdata time
set timefmt "%m/%d/%Y %H:%M:%S"
set format x "%H:%S\n%d/%m"

set ytics nomirror
set y2tics
set format y2 "%.0s %cB/s"

#set tics out
set grid y2

# Commentaire de génération du graphe sous le graphique
set label 33 "Graphique généré le ".strftime("%d-%m-%Y",time(0.0))." par `whoami`." at graph 0.5, character 1 textcolor rgb "grey"
set label 33 center
set label 33 font "Arial,16"

plot  data_file using 1:2 axes x1y1 with linespoints linecolor 11 linewidth 2 pointtype -1 title "cpu(%)", \
      data_file using 1:3 axes x1y2 with linespoints linecolor 12 linewidth 2 pointtype -1 title "émis(Octets/s)", \
      data_file using 1:4 axes x1y2 with linespoints linecolor 13 linewidth 2 pointtype -1 title "reçus(Octets/s)"
</file>